Regarding my script from two weeks ago that updates your status on instant messengers and web services simultaneously, a few amendments:

1. As Zib points out in a comment, it is indeed possible to adjust the script for fewer services. For example, removing the tell application "Skype" block will leave out the Skype aspect, and only update Adium, Facebook and Twitter.
2. It is also possible to integrate this with Growl, so you can get some feedback on when it’s done updating each service. Note that this isn’t necessarily a guarantee that this update actually succeeded; for instance, I at first had a bug where Growl would happily report having updated Facebook’s status, even when Facebook showed no change at all: this notification only refers to a finished attempt.
3. And finally, I admittedly did something lazy by not properly fetching a post_form_id from Facebook, instead opting to hardcode it. That worked fine for me for a few days, but I eventually had to fix it on my end, and this may very well be the reason it never worked for Christopher. My revised version, as posted below, should remedy this (it has worked for me since).

So with all that said, here’s my current version of the script:

using terms from application "Quicksilver"
	on process text NewStatus
		tell application "GrowlHelperApp" to register as application "StatusUpdater" all notifications {"AdiumStatusUpdated", "SkypeStatusUpdated", "TwitterStatusUpdated", "FacebookStatusUpdated"} default notifications {"AdiumStatusUpdated", "SkypeStatusUpdated", "TwitterStatusUpdated", "FacebookStatusUpdated"}
		tell application "Adium" to set my status message to NewStatus
		tell application "GrowlHelperApp" to notify with name "AdiumStatusUpdated" title "Adium status updated" description NewStatus application name "StatusUpdater" icon of application "Adium"
		tell application "Skype" to send command "SET PROFILE MOOD_TEXT " & NewStatus script name "Quicksilver StatusUpdater"
		tell application "GrowlHelperApp" to notify with name "SkypeStatusUpdated" title "Skype status updated" description NewStatus application name "StatusUpdater" icon of application "Skype"
		tell application "Keychain Scripting"
			set twitter_key to first Internet key of current keychain whose server is "twitter.com"
			set twitter_login to quoted form of (account of twitter_key & ":" & password of twitter_key)
		end tell
		set twitter_status to quoted form of ("status=" & NewStatus)
		do shell script "curl --user " & twitter_login & " --data-binary " & twitter_status & " http://twitter.com/statuses/update.json"
		tell application "GrowlHelperApp" to notify with name "TwitterStatusUpdated" title "Twitter status updated" description NewStatus application name "StatusUpdater" icon of application "Twitterrific"
		tell application "Keychain Scripting"
			set facebook_key to first Internet key of current keychain whose server is "login.facebook.com"
			set facebook_username to account of facebook_key
			set facebook_password to password of facebook_key
		end tell
		set facebook_form_id to do shell script "curl -v -k -d email='" & facebook_username & "' -d pass='" & facebook_password & "' -d login=Login -L 'https://login.facebook.com/login.php?m&next=http%3A%2F%2Fm.facebook.com%2Fhome.php' -A 'Mozilla/5.0 (Windows; U; Windows NT 5.1; en-US; rv:1.8.1.3) Gecko/20070309 Firefox/2.0.0.3' --cookie-jar /tmp/facebook-cookie.txt | tr '\\"' '
' | grep -A 2 post_form_id | tail -1"
		do shell script "curl -v -d post_form_id=" & facebook_form_id & " -d status='" & NewStatus & "' -d update='Update' -A 'Mozilla/5.0 (Windows; U; Windows NT 5.1; en-US; rv:1.8.1.3) Gecko/20070309 Firefox/2.0.0.3' --cookie /tmp/facebook-cookie.txt 'http://m.facebook.com/home.php' -L"
		tell application "GrowlHelperApp" to notify with name "FacebookStatusUpdated" title "Facebook status updated" description NewStatus application name "StatusUpdater" icon of application "FMenu"
	end process text
end using terms from

If you don’t want Growl support (shouldn’t make much of a performance difference, however) or don’t have Growl installed, you’ll want to cut out each line starting with tell application "GrowlHelperApp", like so:

using terms from application "Quicksilver"
	on process text NewStatus
		tell application "Adium" to set my status message to NewStatus
		tell application "Skype" to send command "SET PROFILE MOOD_TEXT " & NewStatus script name "Quicksilver StatusUpdater"
		tell application "Keychain Scripting"
			set twitter_key to first Internet key of current keychain whose server is "twitter.com"
			set twitter_login to quoted form of (account of twitter_key & ":" & password of twitter_key)
		end tell
		set twitter_status to quoted form of ("status=" & NewStatus)
		do shell script "curl --user " & twitter_login & " --data-binary " & twitter_status & " http://twitter.com/statuses/update.json"
		tell application "Keychain Scripting"
			set facebook_key to first Internet key of current keychain whose server is "login.facebook.com"
			set facebook_username to account of facebook_key
			set facebook_password to password of facebook_key
		end tell
		set facebook_form_id to do shell script "curl -v -k -d email='" & facebook_username & "' -d pass='" & facebook_password & "' -d login=Login -L 'https://login.facebook.com/login.php?m&next=http%3A%2F%2Fm.facebook.com%2Fhome.php' -A 'Mozilla/5.0 (Windows; U; Windows NT 5.1; en-US; rv:1.8.1.3) Gecko/20070309 Firefox/2.0.0.3' --cookie-jar /tmp/facebook-cookie.txt | tr '\\"' '
' | grep -A 2 post_form_id | tail -1"
		do shell script "curl -v -d post_form_id=" & facebook_form_id & " -d status='" & NewStatus & "' -d update='Update' -A 'Mozilla/5.0 (Windows; U; Windows NT 5.1; en-US; rv:1.8.1.3) Gecko/20070309 Firefox/2.0.0.3' --cookie /tmp/facebook-cookie.txt 'http://m.facebook.com/home.php' -L"
	end process text
end using terms from

If you want Skype removed, you get rid of this line:

tell application "Skype" to send command "SET PROFILE MOOD_TEXT " & NewStatus script name "Quicksilver StatusUpdater"

(And the Growl one underneath no longer makes sense either, of course.)
In case of removing Twitter or Facebook, you’ll also want to remove the respective tell application "Keychain Scripting" preceding it, up until and including end tell.

Enjoy!